SUMAR.SI, SUMAR.SI.CONJUNTO

Vamos a ver funciones matemáticas, y, trigonométricas, vamos a empezar con la función SUMAR.SI, que suma los valores de un intervalo que cumplan el criterio que especifiquemos.

Sintaxis

SUMAR.SI (rango, criterio, [rango_suma])

Esta función tiene tres argumentos.

· Rango. Obligatorio. El rango de celdas que deseamos evaluar. Los valores en blanco y de texto se ignoran. El rango seleccionado puede contener fechas en formato estándar de Excel.

· Criterio. Obligatorio. Es el criterio que puede estar en forma de número, expresión, referencia de celda, texto o función que determina las celdas que se van a sumar. Se pueden incluir caracteres comodines: un signo de interrogación (?) para que coincida con cualquier carácter único, o un asterisco (*) para que coincida con cualquier secuencia de caracteres. Si deseamos buscar un signo de interrogación o un asterisco real, debemos de escribir una tilde (~) antes del carácter.

1. Por ejemplo, "*~?".

Importante: Cualquier criterio de texto o cualquier criterio que incluya los símbolos lógicos o matemáticos debe estar entre comillas dobles ("). Si el criterio es numérico, las comillas dobles no son necesarias.

· Rango_suma. Opcional. Son las celdas que se sumarán, si es que desea sumar celdas a las ya especificadas en el argumento rango. Si omite el argumento rango_suma, Excel suma las celdas especificadas en el argumento rango (las mismas celdas a las que se aplica el criterio).

Rango_suma debe tener el mismo tamaño y forma que rango. Si no es así, el rendimiento puede no ser correcto, es decir, que los valores que nos devuelvan no serán los esperados.

Veamos un ejemplo, en el siguiente modelo de datos.

Queremos sumar todas las celdas que sean superiores a 5000.

En la celda K2, ponemos SUMAR.SI, como argumento rango de criterios, seleccionamos las celdas D2:D20, que son las ventas.

=SUMAR.SI (D2:D20

Punto y coma, como argumento criterio, entre comillas dobles, ponemos “>5000”.

=SUMAR.SI (D2:D20;">5000")

Si se dan cuenta, el argumento rango_suma lo he omitido, quiere decir que ha tomado el mismo rango de celdas que para el argumento rango_criterio para realizar la suma.

Tenemos el total de ventas que son superiores a 5000.

Para el siguiente ejemplo, queremos saber las ventas del comercial Claudia.

En la celda K5, ponemos la función, como argumento rango de criterios1, ponemos el rango B2:B20, que son los comerciales.

=SUMAR.SI (B2:B20

Punto y coma, como argumento criterio, entre comillas dobles, ponemos Claudia.

=SUMAR.SI (B2:B20;"Claudia"

Punto y coma, como argumento rango de suma, ponemos el rango D2:D20 que son las ventas.

Cerramos paréntesis.

=SUMAR.SI (B2:B20;"Claudia"; D2:D20)

Aceptamos, y, tenemos las ventas para Claudia.

En este caso, si he usado el argumento rango_suma, porque la columna rango de criterio es texto.

Tenemos una columna que es comisiones, debemos, primero, calcular las comisiones que le corresponde a cada comercial, lo haremos con la función SI. CONJUNTO.

En la celda E2, ponemos la función, como primer argumento prueba logica1, seleccionamos la celda B2 y la igualamos a la celda D23, que es el primer comercial, fijamos D23.

=SI.CONJUNTO(B2=$D$23

Punto y coma, como argumento valor si verdadero1, seleccionamos la celda E23, y, la fijamos.

=SI.CONJUNTO(B2=$D$23;$E$23

Punto y coma, como argumento prueba logica2, volvemos a seleccionar B2 y la igualamos a la celda D24, la cual fijamos.

=SI.CONJUNTO(B2=$D$23;$E$23;B2=$D$24

Punto y coma, como argumento valor si verdadero2, seleccionamos la celda E24, la cual fijamos.

=SI.CONJUNTO(B2=$D$23;$E$23;B2=$D$24;$E$24

Punto y coma, como argumento prueba logica3, seleccionamos la celda B2 y la igualamos a la celda D25, y, fijamos.

=SI.CONJUNTO(B2=$D$23;$E$23;B2=$D$24;$E$24;B2=$D$25

Punto y coma, como argumento valor si verdadero3, seleccionamos la celda E25, y, fijamos.

=SI.CONJUNTO(B2=$D$23;$E$23;B2=$D$24;$E$24;B2=$D$25;$E$25

Punto y coma, como argumento prueba logica4, seleccionamos la celda B2 y la igualamos a la celda D26, y, fijamos.

=SI.CONJUNTO(B2=$D$23;$E$23;B2=$D$24;$E$24;B2=$D$25;$E$25;B2=$D$26

Punto y coma, como argumento valor si verdadero4, seleccionamos la celda E26, y, fijamos.

=SI.CONJUNTO(B2=$D$23;$E$23;B2=$D$24;$E$24;B2=$D$25;$E$25;B2=$D$26;$E$26

Punto y coma, como argumento prueba logica5, seleccionamos la celda B2 y la igualamos a la celda D27, y, fijamos.

=SI.CONJUNTO(B2=$D$23;$E$23;B2=$D$24;$E$24;B2=$D$25;$E$25;B2=$D$26;$E$26;B2=$D$27

Punto y coma, como argumento valor si verdadero5, seleccionamos la celda E27, y, fijamos.

Cerramos paréntesis.

=SI.CONJUNTO(B2=$D$23;$E$23;B2=$D$24;$E$24;B2=$D$25;$E$25;B2=$D$26;$E$26;B2=$D$27;$E$27)

Aceptamos, y, tenemos la comisión para el primer comercial.

Arrastramos, y, ya tenemos la comisión para cada comercial.

Multiplicamos cada comisión por su venta.

=D2*SI.CONJUNTO(B2=$D$23;$E$23;B2=$D$24;$E$24;B2=$D$25;$E$25;B2=$D$26;$E$26;B2=$D$27;$E$27)

Arrastramos, y, tenemos el importe de comisión para cada comercial.

Ahora, queremos saber el total de comisiones que ha sido superior a 100, para el comercial Jaime.

¿Cómo lo hacemos si la función SUMAR.SI solo acepta un criterio?

Si conocemos el condicional SI, podemos usarlo junto con la función SUMA que sería lo mismo que SUMAR.SI.

Debemos de hacer dos preguntas, una que las comisiones sean superiores a 100, y, otra que el comercial sea Jaime, cosa que puedo hacer con un SI. ANIDADO.

En la celda K8, ponemos el condicional SI, como argumento prueba lógica, vamos a indicar dos condiciones, para ello, abrimos un paréntesis para poner la primera condición, donde señalamos el rango E2:E20, que son las comisiones, ponemos el operador de comparación mayor (>), y, el valor 100.

Cerramos paréntesis de la primera condición.

Ponemos el símbolo de asterisco, que es igual que el operador lógico Y, es decir, devuelve VERDADERO si todas las condiciones se cumplen, y, abrimos otro paréntesis, para la segunda condición.

Seleccionamos el rango B2:B20, que son los comerciales, y, lo igualamos Jaime entre comillas dobles.

Cerramos paréntesis.

=SI((E2:E20>100) *(B2:B20="Jaime")

Punto y coma, como argumento valor si verdadero, seleccionamos el rango E2:E20.

Punto y coma, como argumento valor si falso, ponemos un texto en blanco.

Cerramos paréntesis.

=SI((E2:E20>100) *(B2:B20="Jaime"); E2:E20;"")

Englobamos el condicional SI en la función SUMA.

=SUMA(SI((E2:E20>100)*(B2:B20="Jaime");E2:E20;""))

Aceptamos, y, tenemos el total para el comercial Jaime cuyas ha sido superior a 100.

Ahora, queremos ver las ventas de aquellos comerciales cuya letra final del nombre sea la “s”, para ello, debemos de usar el carácter comodín asterisco primero, y, después poner la letra S.

En la celda K11, ponemos SUMAR.SI, como argumento rango de criterio, seleccionamos el rango B2:B20.

=SUMAR.SI (B2:B20

Punto y coma, como argumento criterio, entre comillas dobles, ponemos “*s”, quiere decir que todo nombre que termine es “s”, la parte izquierda será sustituida por el asterisco.

=SUMAR.SI (B2:B20;"*s"

Punto y coma, como argumento rango de suma seleccionamos el rango D2:D20.

Cerramos paréntesis.

=SUMAR.SI (B2:B20;"*s"; D2:D20)

Aceptamos, y, ya lo tenemos.

Lo siguiente es saber las ventas del comercial Jaime, y, Claudia, dentro de SUMAR.SI, ya sabemos que solo podemos poner una condición, y, tenemos dos condiciones, que ambas deben de cumplirse.

Vamos a ello.

En la celda K14, ponemos la función, como argumento rango de criterio, seleccionamos el rango B2:B20.

=SUMAR.SI(B2:B20

Punto y coma, como argumento criterio, entre comillas dobles, ponemos Jaime.

=SUMAR.SI(B2:B20;"Jaime"

Punto y coma, como argumento rango de suma, seleccionamos el rango D2:D20.

Cerramos paréntesis.

=SUMAR.SI(B2:B20;"Jaime";D2:D20)

Con esto, tenemos las ventas para Jaime, bien, después del cierre de paréntesis, ponemos el signo +, copiamos y pegamos el primer SUMAR.SI, y, cambiamos Jaime por Claudia.

=SUMAR.SI(B2:B20;"Jaime";D2:D20)+SUMAR.SI(B2:B20;"Claudia";D2:D20)

Aceptamos, y, ya tenemos las ventas del comercial Jaime y Claudia.

Vayamos ahora con la función SUMAR.SI.CONJUNTO, esta función funciona igual que SUMAR.SI, pero admite más de un criterio.

Sintaxis

SUMAR.SI.CONJUNTO(rango_suma; rango_criterios1; criterios1; [rango_criterios2; criterios2];...)

En la sintaxis podemos observar a diferencia de la función SUMAR.SI, que el argumento rango_suma es el primero, mientras que en la función SUMAR.SI es el último argumento.

· Rango_suma. Obligatorio. Es el rango por el que se van a sumar las coincidencias.

· Rango_criterios1. Obligatorio. es el rango por donde se va a buscar el primer criterio.

Desde rango_criterios2 en adelante son opcionales, podemos poner hasta 127 condiciones.

Veamos un ejemplo, quiero saber lo que ha ganado el comercial Jaime durante el trimestre1, es decir, desde el día 01/01/2022 hasta el 31/03/2022.

Tenemos dos condiciones, por lo que SUMAR.SI no nos valdría, vamos a usar SUMAR.SI.CONJUNTO.

En la celda K2, ponemos la función, como argumento rango de suma, seleccionamos el rango D2:D20.

=SUMAR.SI.CONJUNTO(D2:D20

Punto y coma, como argumento rango de criterios1, seleccionamos el rango B2:B20.

=SUMAR.SI.CONJUNTO(D2:D20; B2:B20

Punto y coma, como argumento criterios1, entre comillas dobles, ponemos Jaime.

=SUMAR.SI.CONJUNTO(D2:D20; B2:B20; "Jaime"

Punto y coma, como argumento rango de criterios2, seleccionamos el rango A2:A20.

=SUMAR.SI.CONJUNTO(D2:D20; B2:B20; "Jaime"; A2:A20

Punto y coma, como argumento criterios2, entre comillas dobles, ponemos el operador de comparación “>=” y la fecha 01/01/2022.

=SUMAR.SI.CONJUNTO(D2:D20; B2:B20; "Jaime"; A2:A20;">=01/01/2022"

Punto y coma, como argumento rango de criterios3, volvemos a seleccionar el rango A2:A20.

=SUMAR.SI.CONJUNTO(D2:D20; B2:B20; "Jaime"; A2:A20;">=01/01/2022"; A2:A20

Punto y coma, como argumento criterios3, entre comillas dobles, ponemos el operador de comparación <= y la fecha 31/03/2022.

Cerramos paréntesis.

=SUMAR.SI.CONJUNTO(D2:D20; B2:B20; "Jaime"; A2:A20;">=01/01/2022"; A2:A20;"<=31/03/2022")

Aceptamos, y, tenemos el total para el comercial, o, vendedor Jaime para el primer trimestre.

Para el siguiente ejemplo, tenemos un modelo donde tenemos la venta de productos en diferentes centros comerciales, provincias, y, fechas.

El modelo esta en formato de tabla, y, se llama ventas.

Queremos calcular el total para las ventas realizadas en el C.C. Nervión, en las provincias que empiezan por la letra S, entre los meses 1 al 6, y, los días del 1 al día 15.

En la celda J7, ponemos la función SUMAR.SI.CONJUNTO.

Como argumento rango de suma, seleccionamos la columna de total.

=SUMAR.SI.CONJUNTO(Ventas[Total]

Punto y coma, como argumento rango de criterios1, seleccionamos la columna de provincia.

=SUMAR.SI.CONJUNTO(Ventas[Total];Ventas[Provincia]

Punto y coma, como argumento criterios1, entre comillas dobles, ponemos “S*”.

=SUMAR.SI.CONJUNTO(Ventas[Total];Ventas[Provincia];"S*"

Punto y coma, como argumento rango de criterios2, ponemos la columna de centro.

=SUMAR.SI.CONJUNTO(Ventas[Total];Ventas[Provincia];"S*";Ventas[Centro]

Punto y coma, como argumento criterios2, seleccionamos la celda E2, que contiene el centro a buscar.

=SUMAR.SI.CONJUNTO(Ventas[Total];Ventas[Provincia];"S*";Ventas[Centro];E2

Punto y coma, como argumento rango de criterios3, seleccionamos la columna de mes.

=SUMAR.SI.CONJUNTO(Ventas[Total];Ventas[Provincia];"S*";Ventas[Centro];E2;Ventas[Mes]

Punto y coma, como argumento criterios3, entre comillas dobles ponemos “>=1”.

=SUMAR.SI.CONJUNTO(Ventas[Total];Ventas[Provincia];"S*";Ventas[Centro];E2;Ventas[Mes];">=1"

Punto y coma, como argumento rango de criterios4, seleccionamos, de nuevo, la columna de mes.

=SUMAR.SI.CONJUNTO(Ventas[Total];Ventas[Provincia];"S*";Ventas[Centro];E2;Ventas[Mes];">=1";Ventas3[Mes]

Punto y coma, como argumento criterios4, entre comillas dobles, ponemos “<=6”.

=SUMAR.SI.CONJUNTO(Ventas[Total];Ventas[Provincia];"S*";Ventas[Centro];E2;Ventas[Mes];">=1";Ventas[Mes];"<=6"

Punto y coma, como argumento rango de criterios5, seleccionamos la columna día.

=SUMAR.SI.CONJUNTO(Ventas[Total];Ventas[Provincia];"S*";Ventas[Centro];E2;Ventas[Mes];">=1";Ventas[Mes];"<=6";Ventas[Dia]

Punto y coma, como argumento criterios5, entre comillas dobles, ponemos “>1”.

=SUMAR.SI.CONJUNTO(Ventas[Total];Ventas[Provincia];"S*";Ventas[Centro];E2;Ventas[Mes];">=1";Ventas[Mes];"<=6";Ventas[Dia];">=1"

Punto y coma, como argumento rango de criterios6, seleccionamos, de nuevo, la columna día.

=SUMAR.SI.CONJUNTO(Ventas[Total];Ventas[Provincia];"S*";Ventas[Centro];E2;Ventas[Mes];">=1";Ventas[Mes];"<=6";Ventas[Dia];">=1";Ventas[Dia]

Punto y coma, como argumento criterios6, ente comillas dobles, ponemos “<=15”.

Cerramos paréntesis.

=SUMAR.SI.CONJUNTO(Ventas3[Total];Ventas3[Provincia];"S*";Ventas3[Centro];E2;Ventas3[Mes];">=1";Ventas3[Mes];"<=6";Ventas3[Dia];">=1";Ventas3[Dia];"<=15")

Aceptamos, y, ya tenemos el total.

Cálculo de porcentajes

Seguimos trabajando con el modelo que suelo usar habitualmente.

Queremos calcular los ingresos totales, porcentaje por columna, porcentaje del total principal, y, porcentaje total de la fila principal.

Estos cálculos lo podemos hacer a través de una tabla dinámica, vamos a hacerlo, para ello, con una celda dentro del modelo, vamos a la pestaña de insertar, y, hacemos clic en tabla dinámica.

En la siguiente ventana, marcamos hoja de cálculo existente, y, seleccionamos una celda donde colocarla.

Aceptamos.

Llevamos a filas en centro, y, producto, y, a valores, llevo total.

Cuando hemos bajado a fila, el centro y producto, es lo que se conoce como una relación padre-hijo, la lista única de centros es el padre, pero cada centro puede tener varios hijos, es decir, un centro puede tener varios productos.

Seguimos.

Para ver mejor el modelo, vamos a ponerlo en formato tabular, para ello, con una celda dentro de la tabla dinámica, vamos a la pestaña diseño, desplegamos diseño de informe, y, seleccionamos mostrar en formato tabular.

Seleccionamos una celda dentro de la columna suma de total, hacemos clic con botón alternativo de ratón, y, seleccionamos formato de número.

Se abre la ventana formato de celdas, en la ventana categoría, seleccionamos moneda, y, le damos dos decimales.

Aceptamos.

Tenemos el total para cada producto de cada centro comercial, y, después el total por centro.

Ahora, tenemos que calcular el porcentaje del total de la columna, para ello, volvemos a bajar a valores, la columna de total.

Hacemos clic con botón alternativo de ratón sobre una celda en la columna suma de total2, y, desplegamos mostrar valores como, y, seleccionamos % del total de columnas.

Vemos el porcentaje que corresponde a cada venta de producto en el centro comercial, y, el porcentaje total del centro comercial, que es la parte que le corresponde respecto al total general.

Podemos ver en la fila del total general, que la suma de todos los porcentajes de cada centro es el 100%.

Ahora, vamos a calcular el porcentaje que corresponde a cada producto respecto al centro, es decir, si vemos el centro comercial Nervión, vemos los productos, y, el total por producto para dicho centro, pues vamos a calcular el porcentaje de esa cantidad por producto, respecto al total del centro comercial.

Volvemos a bajar la columna total a valores.

Volvemos a hacer clic con botón alternativo de ratón, desplegamos mostrar valores como, y, seleccionamos % del total principal.

Se abre la ventana mostrar valores como, seleccionamos la columna centro y aceptamos.

Podemos ver como al centro comercial Nervión, le corresponde el 100%, y, para los productos, es el porcentaje que le corresponde respecto a dicho total.

Vamos a volver a bajar total a valores.

Hacemos clic con botón alternativo de ratón, desplegamos mostrar valores como, y, seleccionamos % del total de filas principales.

Podemos ver los mismos porcentajes que la columna suma de total3, pero vemos que el total para el centro comercial Nervión, no es el 100%, sino el porcentaje que corresponde respecto al total general, es decir, es una combinación de la columna suma de total2, y, suma de total3.

Antes hemos hablado de la relación padre-hijo, en este caso, el porcentaje para cada producto, producto es el hijo, lo calcula con el total del padre, pero cuando llega al total del centro comercial.

No hay ningún padre, así que lo comparara con el total de la columna.

Sabemos que cuando introducimos datos nuevos, la tabla dinámica no se actualiza de forma automática, pues, es por esa razón que lo vamos a hacer con fórmulas.

Ahora, vamos a hacer lo mismo, pero con fórmulas.

Tengo el mismo modelo que la tabla dinámica, pero en Excel.

Lo primero que tenemos que calcular es el total por producto para cada centro comercial.

Para ello, vamos a usar la función SUMAR.SI.CONJUNTO, como argumento rango de suma, seleccionamos la columna de total.

=SUMAR.SI.CONJUNTO(Venta[Total]

Como argumento rango de criterios1, seleccionamos la columna de centro.

=SUMAR.SI.CONJUNTO(Venta[Total];Venta[Centro]

Como argumento criterio1, seleccionamos la celda G7, que es el centro comercial Nervión.

=SUMAR.SI.CONJUNTO(Venta[Total];Venta[Centro];G7

Como argumento rango de criterios2, seleccionamos la columna de producto.

=SUMAR.SI.CONJUNTO(Venta[Total];Venta[Centro];G7;Venta[Producto]

Como argumento criterio2, seleccionamos la celda H2, que es el primer producto para el centro comercial Nervión.

Cerramos paréntesis y aceptamos.

=SUMAR.SI.CONJUNTO(Venta[Total];Venta[Centro];G7;Venta[Producto];H2)

Tenemos el total para el producto aspiradora del centro comercial Nervión.

Arrastramos, y, tenemos los totales por producto, y, centro comercial, pero vemos que después del último producto, como total aparece cero, porque no hay coincidencias.

Ahí, debe de aparecer el total por centro comercial, pues, vamos a modificar la expresión anterior, con el condicional SI, voy a preguntar que, si el valor de la celda H2 es blanco, en ese caso, caso, con la función SUMAR.SI, que calcule el total, siempre que la columna centro sea igual al valor de G2, en caso contrario, que realice el SUMAR.SI.CONJUNTO.

Como H2, no es blanco, realizar el argumento valor si falso, igual, para las celdas H3, H4, H5, y, H6, entonces, llega a la celda H6, que, si es blanco, entonces, realizar el argumento valor si verdadero, donde calcula el total siempre que la columna centro sea igual al valor de la celda G7.

=SI(ESBLANCO(H2);SUMAR.SI(Venta[Centro];G2;Venta[Total]);SUMAR.SI.CONJUNTO(Venta[Total];Venta[Centro];G2;Venta[Producto];H2))

Aceptamos, y, arrastramos, y, vemos los totales por centro, que, si lo comparamos con los resultados de la tabla dinámica, vemos que son los mismos.

Antes de seguir, vamos a calcular el total general, para ello, voy a preguntar que si el rango H2:H37 es diferente a blanco.

=SI(H2:H37<>""

En ese caso, que me devuelva un texto en blanco.

=SI(H2:H37<>"";""

En caso contrario, que me devuelva el valor del rango I2:I37.

Cerramos paréntesis.

=SI(H2:H37<>"";"";I2:I37)

Como queremos el total, después del signo igual, usamos la función SUMA.

=SUMA(SI(H2:H37<>"";"";I2:I37))

Ya tenemos el total de la columna centro, que, si miramos la tabla dinámica, es el mismo.

Ahora, tenemos que calcular que porcentaje corresponde cada valor con el total general, es decir, el % total de columnas, esta operación es sencilla, porque solo debemos de dividir el valor de I2, entre el total general que hemos calculado anteriormente, y, la fijamos.

=I2/$I$38

Arrastramos, y, tenemos el porcentaje al que corresponde cada valor respecto al total.

Vamos a donde calculamos el total general por centro, fijamos H2:H37, y, arrastramos hacia la derecha.

=SUMA(SI($H$2:$H$37<>"";"";J2:J37))

Vemos que nos devuelve el 100%.

Lo siguiente es calcular el porcentaje del total principal.

¿Qué diferencia hay entre el cálculo anterior?

Tenemos las ventas de cada producto por centro comercial, pues, ahora, debemos de calcular el porcentaje que corresponde la venta de cada producto, respecto al total por centro comercial.

Tenemos que hacer dos preguntas, la primea de ellas, ¿es blanco H2?.

=SI(ESBLANCO(H2)

Si es blanco, vamos a dividir el total entre si mismo, lo que nos dará el 100%.

=SI(ESBLANCO(H2);I2/I2

Esto pasara cuando H2 sea blanco, pero si no lo es, debe de calcular el porcentaje de cada producto respecto al total, es decir, calcular las ventas con la función SUMAR.SI, siempre que la columna centro sea igual al valor de la celda G2.

Cuando arrastremos, la condición ESBLANCO, no se va a cumplir hasta llegar a la celda H7, quiere decir, que calculara el total para el centro comercial Nervión.

Cerramos paréntesis y aceptamos.

=SI(ESBLANCO(H2);I2/I2;I2/SUMAR.SI(Venta[Centro];G2;Venta[Total]))

Vemos que tenemos el mismo porcentaje que el obtenido en la tabla dinámica.

Arrastramos, y, podemos ver como al final de cada producto, aparece el 100% para centro comercial.

Si lo comparamos con la tabla dinámica, vemos que son los mismos.

Lo siguiente es calcular la mezcla entre los dos porcentajes calculados anteriormente, quiere decir, que debemos de calcular el porcentaje de cada producto respecto al total por centro comercial, y, el porcentaje de cada centro comercial debe de ser respecto al total general.

Para el cálculo del porcentaje respecto al total de cada centro comercial, usamos la expresión anterior.

=I2/$I$7

Tenemos el mismo porcentaje.

Ahora, debemos de calcular el porcentaje de cada centro respecto al total, para ello, pregunto de nuevo si es blanco H2, en ese caso, que calcule la suma del total para el centro comercial, y, lo divida entre la suma de la columna total.

=SI(ESBLANCO(H2);SUMAR.SI(Venta[Centro];G2;Venta[Total])/SUMA(Venta[Total])

En caso contrario, tiene que dividir el valor de I2, entre la suma total del centro comercial, que es mismo SUMAR.SI, que acabamos de usar.

=SI(ESBLANCO(H2);SUMAR.SI(Venta[Centro];G2;Venta[Total])/SUMA(Venta[Total]);I2/SUMAR.SI(Venta[Centro];G2;Venta[Total]))

Aceptamos, y, arrastramos, si comparamos con las dos columnas anteriores, vemos que los resultados son los mismos.

Pues, ya tenemos nuestro ejercicio realizado.

Miguel Angel Franco Garcia