SUMAPRODUCTO

Antes de explicar esta función, veamos un ejemplo de cómo calcular el total.

Tenemos le siguiente modelo:

Primero, vamos a calcular las unidades por el precio para cada fila, para ello, multiplicamos unidades por precio.

Aceptamos, y, arrastramos hacia abajo.

Lo siguiente que debemos de hacer es calcular el total, es decir, la suma de la columna total, para ello, usamos la función SUMA.

Aceptamos, y, ya tenemos el total.

Podemos ver que hemos dado un primer paso para multiplicar unidades por precio, hemos dado un segundo paso, para arrastrar la formula, y, un tercer paso para sumar las cantidades de totales.

Pues la función SUMAPRODUCTO, hace todos los pasos anteriores en uno.

La función SUMAPRODUCTO tiene la siguiente sintaxis:

· Matriz1. Primera matriz para multiplicar.

· Matriz2. Segunda matriz para multiplicar.

A partir de matriz3, son argumentos opcionales, donde podemos poner hasta 255 matrices.

Pues, vamos a calcular el total pero con la función SUMAPRODUCTO, para ello, en una celda escribimos la siguiente sintaxis:

=SUMAPRODUCTO(D4:D8;E4:E8)

Vemos que tenemos el mismo resultado que hemos obtenido anteriormente.

Veamos cómo funciona internamente la función SUMAPRODUCTO, pues estos son los cálculos que dicha función realiza internamente.

=D4*E4+D5*E5+D6*E6+D7*E7+D8*E8

Vemos que realiza los mismos cálculos que hemos realizado manualmente.

También, podemos usar la función SUMAPRODUCTO, para calcular la media ponderada.

¿Qué es la media ponderada?

Bien, cuando tenemos una serie de valores en vertical, o, en horizontal, pues, seleccionamos los datos y, y, calculamos el promedio.

Pero, hay veces, que tenemos una serie de números, y, justo debajo de ellos, tenemos otros valores, que es el peso que tiene cada valor, en este caso, no podemos calcular un promedio, en este caso, debemos de calcular una media ponderada.

¿Cómo se calcula la media ponderada?

Veamos un ejemplo, tenemos los siguientes valores.

Vemos valores, y, justo debajo de ellos, un peso, que va a acorde con el valor que tenemos.

Primero, vamos a cálculo de forma manual, para ello, debemos de multiplicar el primer valor por su peso, pues lo hacemos y arrastramos hacia la derecha.

Lo siguiente que debemos de hacer es sumar dichos resultados.

=SUMA(B4:E4)

Y, estos resultados lo dividimos entre la suma de los pesos.

=SUMA(B4:E4)/SUMA(B3:E3)

Ya tenemos la media ponderada, que es 80.

Pues, ahora lo vamos a hacer con la función SUMAPRODUCTO.

Vemos que obtenemos le mismo resultado.

Vamos a ver otro ejemplo.

Tenemos los siguientes datos.

Queremos saber que cantidad de ventas de cerezas ha hecho el vendedor Jaime.

En la celda C10, escribo lo siguiente:

=SUMAPRODUCTO(

En el argumento matriz1, escribo:

Con esta expresión, vamos a multiplicar el número de veces que aparece Jaime por el número de veces que aparece cereza.

Y como matriz2 va a ser el rango de ventas.

=SUMAPRODUCTO((A2:A7=A10)*(B2:B7=B10);C2:C7)

Aceptamos, y, podemos ver las ventas para el producto cerezas del comercial Jaime.

Veamos cómo funciona esta función, con la celda seleccionada, vamos a ir a la pestaña formulas, y, hacer clic en evaluar formula.

Se abre la ventana de evaluar formula, donde en la ventana referencia, vemos la formula, donde vemos subrayado la celda A10, que es el primer criterio.

Hacemos clic en evaluar.

Si recordamos, la primera expresión es A2:A7 = A10, en este caso, vemos los valores del rango A2:A7, después, el signo igual, y, el valor de A10, es decir:

Seguimos, hacemos clic en evaluar de nuevo.

Aparece la siguiente ventana, donde, podemos observar que ahora ha puesto VERDADERO donde hay coincidencia, y, FALSO donde no la hay.

Si nos fijamos en el modelo de datos, podremos ver que A2 es igual a Jaime, de ahí el valor de VERDADERO, pero que A3 no lo es, por eso aparece FALSO, y, lo mismo para el resto de las celdas.

Hacemos clic de nuevo en evaluar.

En la siguiente ventana trata la siguiente cadena, es decir, B2:B7 = B10, es decir, va a comparar la matriz de frutas con cereza.

Hacemos clic en evaluar.

Igual que antes, nos aparecen las frutas a que equivale el rango B2:B7, y, el valor de B10, que es cereza.

Volvemos a hacer clic en evaluar.

Vuelve a aparecer VERDADERO o FALSO según haya coincidencia.

Hacemos clic en evaluar, y aparecen subrayadas todos los VERDADEROS y FALSOS.

Hacemos clic de nuevo en evaluar.

Aparecen con unos las coincidencias, si vemos el modelo de datos.

Vemos en el modelo donde deben de aparecer esos unos, que es donde pertenece al comercial Jaime.

Hacemos clic de nuevo en evaluar.

Y vemos el resultado que tenemos, por lo que ya sabemos de dónde sale dicho número.

Veamos otro ejemplo, tenemos los siguientes datos, donde vemos que tenemos ventas, y, retenciones en negativos.

Quiere decir que el total es ventas menos retenciones.

Pero, queremos calcular el total para el comercial Claudia.

Manualmente, vamos a calcular como quedaría el total, para ello, nos colocamos en la celda B8, usamos la función SUMAR.SI, donde como argumento rango, seleccionamos los vendedores, como argumento criterio, ponemos Claudia, como argumento rango de suma, seleccionamos las ventas.

Cerramos paréntesis.

=SUMAR.SI(A2:A7;A3;B2:B7)

Tenemos el total de ventas para la vendedora Claudia.

Usamos otro SUMAR.SI para calcular las retenciones para Claudia.

=SUMAR.SI(A2:A7;A3;C2:C7)

Sumamos ambas cantidades, y, tenemos las ventas para Claudia.

Pues, ahora, lo vamos a hacer con la función SUMAPRODUCTO, donde ya vamos a especificar el criterio.

Como matriz1, suma ambas columnas, que me devolverá la misma diferencia calculada anteriormente.

=SUMAPRODUCTO(B2:B7+C2:C7)

Ahora, tenemos que especificar el criterio, anteriormente, hemos visto que podemos especificar mas de un criterio, encerrando entre paréntesis el criterio, o, los criterios, seguido del símbolo de asterisco, pues, es lo que vamos a hacer.

=SUMAPRODUCTO(B2:B7+C2:C7*(A2:A7="Claudia"))

Y tenemos el total para el vendedor Claudia.

¿Es correcto este resultado?

La respuesta, es NO, ¿Por qué?, por la prioridad de operadores, si nos fijamos en la expresión:

=SUMAPRODUCTO(B2:B7+C2:C7*(A2:A7="Claudia"))

Estamos usando el operador mas (+), junto con el operador de multiplicación (*), ¿Qué operador tiene prioridad sobre el otro?, pues, el operador de multiplicación (*), tiene prioridad sobra la suma, esto quiere decir, que primero hace la siguiente expresión:

C2:C7*(A2:A7="Claudia")

Donde sumará las retenciones del vendedor Claudia, y, después hará la siguiente expresión:

= B2:B7

De ahí el resultado, pero, vimos en el nivel básico, que debíamos de hacer para dar prioridad a una operación, que era, encerrarla entre paréntesis, pues, vamos a encerrar entre paréntesis, la operación de suma.

=SUMAPRODUCTO((B2:B7+C2:C7)*(A2:A7="Claudia"))

Ahora, tenemos el resultado correcto, que es 28.