PROMEDIO/PROMEDIOA

La función PROMEDIO devuelve el promedio, conocido como la media aritmética de los argumentos.

Sintaxis

PROMEDIO(número1; [número2]; ...)

· Número1, es un argumento obligatorio. Que es el número, referencia de celda o rango para el cual desea el promedio.

· Número2, argumento opcional. Números, referencias de celda o rangos adicionales para los que desea el promedio, podemos poner hasta un máximo de 255.

Cuando se calcula el promedio, no se tiene en cuenta los valores lógicos, ni los valores de texto, ni celdas vacías, dichos valores se pasan por alto, si queremos usar dichos valores, debemos de usar la función PROMEDIOA.

El PROMEDIO manual se calcula sumando las cantidades, y, dividiéndola en el número de cantidades.

Veamos un ejemplo, de cómo calcula la media aritmética de una serie de datos, tenemos los siguientes datos, vamos a calcular el promedio de la columna ventas.

Debemos de sumar las ventas, y, dividirlas entre el numero de cantidades, para ello, usamos la función SUMA, como argumento seleccionamos las ventas, y, cerramos paréntesis.

=SUMA(D2:D20)

Ponemos el operador de división, para contar las celdas, podemos usar la función CONTAR.

=SUMA(D2:D20)/CONTAR(D2:D20)

Aceptamos, y, tenemos el promedio.

Pero, por supuesto, es más rápido el uso de la función PROMEDIO, escribimos el signo igual seguido de la función PROMEDIO, y, especificamos el rango de celdas.

=PROMEDIO(D2:D20)

Vemos que tenemos el mismo resultado obtenido de la forma manual.

Pero si queremos saber el promedio, pero de cada vendedor, pues, PROMEDIO ya no nos valdría, en este caso, debemos de usar PROMEDIO.SI, que calculara el promedio si la condición que le pongamos se cumpla.

Sintaxis

PROMEDIO.SI(rango; criterios; [rango_promedio])

· Rango, argumento obligatorio. Una o más celdas cuyo promedio deseamos obtener que incluyan números, o nombres, matrices o referencias que contengan números.

· Criterio, argumento obligatorio. Criterio en forma de número, expresión, referencia de celda o texto que determina las celdas cuyo promedio se va a obtener.

· Rango_promedio, argumento opcional. Conjunto de celdas cuyo promedio se va a calcular. Si se omite, se utiliza el argumento rango.

No se tienen en cuenta valores lógicos, ni celdas vacías, si el argumento criterio, ponemos blanco, se cuenta como cero, si no hay celdas que cumplan con la condición, devuelve un error, podemos usar los caracteres comodines.

Tenemos los siguientes datos:

En la celda G5, ponemos PROMEDIO.SI, como argumento rango, seleccionamos los vendedores.

=PROMEDIO.SI(B2:B20

Punto y coma, como argumento criterio, seleccionamos la celda F5.

=PROMEDIO.SI(B2:B20;f5

Punto y coma, como argumento rango_promedio, seleccionamos las ventas.

Cerramos paréntesis.

=PROMEDIO.SI(B2:B20;F5;D2:D20)

Aceptamos, y, tenemos el promedio de ventas para la vendedora Claudia.

Fijamos las siguientes referencias:

=PROMEDIO.SI($B$2:$B$20;F5;$D$2:$D$20)

Arrastramos y tenemos el promedio de ventas para cada vendedor.

Si queremos saber el promedio por vendedor y trimestre, debemos de usar PROMEDIO.SI.CONJUNTO, que es igual que PROMEDIO.SI, pero admite mas de una condición, la diferencia en la sintaxis es que en la función PROMEDIO.SI, el argumento rango_promedio es el último, y, en la función PROMEDIO.SI.CONJUNTO, el argumento rango_promedio es el primero.

En la celda G13, ponemos PROMEDIO.SI.CONJUNTO, como argumento rango_promedio, seleccionamos las ventas.

=PROMEDIO.SI.CONJUNTO(D2:D20

Punto y coma, como argumento rango_criterios1, seleccionamos los vendedores.

=PROMEDIO.SI.CONJUNTO(D2:D20;B2:B20

Punto y coma, como argumento criterio1, seleccionamos la celda F13.

=PROMEDIO.SI.CONJUNTO(D2:D20;B2:B20;F13

Punto y coma, como argumento rango_criterios2, seleccionamos los trimestres.

=PROMEDIO.SI.CONJUNTO(D2:D20;B2:B20;F13;C2:C20

Punto y coma, como argumento criterio2, seleccionamos la celda G12.

Cerramos paréntesis.

=PROMEDIO.SI.CONJUNTO(D2:D20;B2:B20;F13;C2:C20;G12)

Aceptamos.

Tenemos el promedio de ventas para la vendedora Claudia para el trimestre 1.

Fijamos las siguientes celdas:

=PROMEDIO.SI.CONJUNTO($D$2:$D$20;$B$2:$B$20;$F13;$C$2:$C$20;G$12)

Nos colocamos en la celda G13, pulsamos CTRL mas C para copiar, seleccionamos el rango donde vamos a pegar, y, pulsamos CTRL más V para pegar.

Ya tenemos el promedio para cada vendedor y trimestre.

Vemos que tenemos algunos errores de división por cero, y, es porque no hay ventas para ese periodo, para quitar el error vamos a usar la función SI.ERROR, donde como argumento valor, es la expresión anterior, y, como argumento valor si error, ponemos un texto en blanco.

Volvemos a copiar y pegar.

Veamos, ahora, la función PROMEDIOA, que calcula el promedio (media aritmética) de los valores alfanuméricos en la lista de argumentos.

La sintaxis es la misma que la de PROMEDIO.

· Los argumentos pueden ser números; nombres, matrices o referencias que contienen números; representaciones textuales de números; o valores lógicos, como VERDADERO y FALSO en una referencia.

· Se tienen en cuenta los valores lógicos y las representaciones textuales de números escritos en la lista de argumentos.

· Los argumentos que contengan VERDADERO se evaluarán como 1; los argumentos que contengan FALSO se evaluarán como 0 (cero).

· Los argumentos que sean matrices o referencias que contengan texto se evaluarán como 0 (cero). El texto vacío ("") se evaluará también como 0 (cero).

· Los argumentos que son valores de error provocan errores.

Siguiendo con el ejemplo anterior, si volvemos a calcular el promedio de la columna ventas.

=PROMEDIOA(D2:D20)

Obtenemos el mismo resultado.

Vamos a cambiar un valor numérico por un número.