Presidentes segunda palabra con B

Jaime Franco Jimenez
12 sept 2023
2 Min. de lectura

Para el siguiente ejemplo, tenemos una serie de presidentes de Estados Unidos.

Para el primer ejercicio, debemos de encontrar aquellos presidentes cuya segunda palabra, o, primer apellido contenga la letra “B”.

En la celda B2, usamos la función ENCONTRAR, como argumento texto buscado, ponemos un espacio, como argumento dentro del texto, seleccionamos el rango A2:A47.

=ENCONTRAR(" ";A2:A47)

Obtenemos una matriz desbordada con la posición del espacio.

Ahora, restamos la longitud de cada cadena menos la posición del espacio.

=LARGO(A2:A47)-ENCONTRAR(" ";A2:A47)

Obtenemos los caracteres a extraer por la derecha, porque vamos a trabajar con la segunda palabra, o, apellido.

Usamos la función HALLAR, que no distingue entra mayúsculas, y, minúsculas, como argumento texto buscado, ponemos la letra B, como argumento dentro del texto, ponemos la función DERECHA, como argumento texto, seleccionamos el rango A2:A47, como argumento numero de caracteres, es la resta anterior.

=HALLAR("b";DERECHA(A2:A47;LARGO(A2:A47)-ENCONTRAR(" ";A2:A47)))

Obtenemos una matriz desbordada con error donde o hay coincidencia, y, la posición de la letra B donde se encuentra.

Preguntamos si es número.

=ESNUMERO(HALLAR("b";DERECHA(A2:A47;LARGO(A2:A47)-ENCONTRAR(" ";A2:A47))))

Obtenemos VERDADERO donde hay coincidencia, y, FALSO donde no la hay.

Ahora, filtramos el rango A2:A47, siempre que el resultado de ESNUMERO es igual a VERDADERO.

=FILTRAR(A2:A47;ESNUMERO(HALLAR("b";DERECHA(A2:A47;LARGO(A2:A47)-ENCONTRAR(" ";A2:A47)))))

Ya lo tenemos.

Para el segundo ejemplo, hay que realizar lo mismo, pero, los presidentes cuyo apellido comienza por la letra B.

Volvemos a encontrar el espacio, y, sumamos 1, que es donde empieza la primera letra del apellido.

=ENCONTRAR(" ";A2:A47)+1

Vamos a extraer de cada cadena, a partir de la posición obtenida 1 carácter, para ello, usamos EXTRAE, como argumento texto, seleccionamos el rango A2:A47, como argumento posición inicial, es la función ENCONTRAR, y, como argumento número de caracteres, ponemos 1.

=EXTRAE(A2:A47;ENCONTRAR(" ";A2:A47)+1;1)

Igualamos a B.

=EXTRAE(A2:A47;ENCONTRAR(" ";A2:A47)+1;1)="B"

Tenemos VERDADERO donde hay coincidencia, y, FALSO donde no la hay.

Filtramos el rango A2:A47, siempre que el resultado de la expresión anterior sea igual a VERDADERO.

=FILTRAR(A2:A47;EXTRAE(A2:A47;ENCONTRAR(" ";A2:A47)+1;1)="B")

Pues, ya lo tenemos.

Para el tercer ejercicio, debemos de extraer los presidentes que tengan dos apellidos, para ello, debemos de encontrar la posición del segundo espacio, si dicho espacio existe, quiere decir que hay un segundo apellido, para ello, volvemos a usar ENCONTRAR, donde volvemos a buscar el espacio en el rango A2:A47, pero usamos el argumento numero inicial, que es la posición del primer guion más 1.

Obtenemos la posición del segundo espacio donde lo haya, y, error donde no lo hay.