Palabras tautónicas

Tenemos las siguientes palabras:

Las palabras tautónicas son aquellas en las que una mitad de la palabra es igual a la otra mitad, pues, en eso consiste el ejercicio, debemos de crear un informe con las palabras que son tautónicas.

Creamos una variable, usamos LARGO como argumento seleccionamos el rango A2:A10, vamos a obtener la longitud de cada cadena, probamos variable.

=LET(a;LARGO(A2:A10);a)

Creamos otra variable, dividimos la variable “a” entre dos.

=LET(a;LARGO(A2:A10);b;a/2;b)

Usamos la función REDOMDEAR.MENOS, es decir, redondear el entero inferior mas cercano, como argumento numero es la división, como argumento numero de decimales, ponemos 0.

=LET(a;LARGO(A2:A10);b;REDONDEAR.MENOS(a/2;0);b)

Tenemos los caracteres a extraer por la izquierda, y, por la derecha.

Creamos otra variable, usamos APILARH, como argumento matriz1, usamos IZQUIERDA, como argumento texto, seleccionamos el rango A2:A10, como argumento numero de caracteres, ponemos la variable “b”, como argumento matriz2, usamos la funcion DERECHA, como argumento texto, volvemos a seleccionar el rango A2:A10, como argumento numero de caracteres, volvemos a poner la variable “b”.

Vamos a obtener dos columnas, en la primera columna, tenemos la mitad de los caracteres, y, en la segunda columna, la otra mitad de caracteres.

=LET(a;LARGO(A2:A10);b;REDONDEAR.MENOS(a/2;0);c;APILARH(IZQUIERDA(A2:A10;b);DERECHA(A2:A10;b));c)

Como la primera letra aparece en mayúsculas, en la funcion IZQUIERDA, usamos la funcion MINUSC.

=LET(a;LARGO(A2:A10);b;REDONDEAR.MENOS(a/2;0);c;APILARH(MINUSC(IZQUIERDA(A2:A10;b));DERECHA(A2:A10;b));c)

Creamos otra variable, donde vamos a comparar la primera columna con la segunda columna, usamos la funcion IGUAL, como argumento texto1, usamos INDICE, como argumento matriz, ponemos la variable “c”, ignoramos le argumento numero de fila, como argumento numero de columna, ponemos 1.

=LET(a;LARGO(A2:A10);b;REDONDEAR.MENOS(a/2;0);c;APILARH(MINUSC(IZQUIERDA(A2:A10;b));DERECHA(A2:A10;b));d;IGUAL(INDICE(c;;1)

Como argumento texto2, usamos el mismo INDICE anterior, pero, en el argumento numero de columna, ponemos 2.

=LET(a;LARGO(A2:A10);b;REDONDEAR.MENOS(a/2;0);c;APILARH(MINUSC(IZQUIERDA(A2:A10;b));DERECHA(A2:A10;b));d;IGUAL(INDICE(c;;1);INDICE(c;;2));d)

Obtenemos una matriz desbordada con VERDADERO donde se cumple la condición, y, FALSO donde no hay coincidencia.

Usamos el argumento calculo de LET, usamos FILTRAR, como argumento array, seleccionamos el rango A2:A10, como argumento Include, ponemos la variable “d”.

=LET(a;LARGO(A2:A10);b;REDONDEAR.MENOS(a/2;0);c;APILARH(MINUSC(IZQUIERDA(A2:A10;b));DERECHA(A2:A10;b));d;IGUAL(INDICE(c;;1);INDICE(c;;2));FILTRAR(A2:A10;d))

Aceptamos, y, ya lo tenemos.

Miguel Angel Franco