Ordenado por cesionario y prioridad

Tenemos los siguientes cesionarios y prioridades.

Debemos de crear una columna donde de forma ordenada debe de aparecer el cesionario y la prioridad, como sigue:

En la celda D2, usamos LET, creamos una variable, transponemos el rango A2:B13, y, probamos variable.

=LET(a;TRANSPONER(A2:B13);a)

Obtenemos una matriz desbordada de dos filas y 12 columnas, donde en la primera fila, tenemos el cesionario, y, en la segunda fila, los resultados.

Creamos otra variable, usamos la función ORDENAR, como argumento matriz es la variable “a”, como argumento ordenar índice, ponemos 2, omitimos el argumento criterio de ordenación, como argumento por col, ponemos VERDADERO.

=LET(a;TRANSPONER(A2:B13);b;ORDENAR(a;2;;VERDADERO);b)

Obtenemos una matriz desbordada igual que la anterior, pero, ordenada por columnas y por la segunda fila.

Creamos otra variable, volvemos a usar ORDENAR, como argumento matriz ponemos la variable “b”, como argumento ordenar índice, ponemos 1, omitimos el argumento criterio de ordenación, como argumento por col, ponemos VERDADERO.

=LET(a;TRANSPONER(A2:B13);b;ORDENAR(a;2;;VERDADERO);c;ORDENAR(b;1;;VERDADERO);c)

Obtenemos la misma matriz obtenida anteriormente, pero ordenada por la primera fila y por columna.

Creamos otra variable usamos la función UNICOS, como argumento matriz ponemos la variable “c”, como argumento by col ponemos VERDADERO para que nos devuelva los valores únicos por columnas.

=LET(a;TRANSPONER(A2:B13);b;ORDENAR(a;2;;VERDADERO);c;ORDENAR(b;1;;VERDADERO);d;UNICOS(c;VERDADERO);d)

Como argumento calculo de LET, usamos ENCOL, como argumento matriz, ponemos la variable “d”, omitimos el argumento ignorar, como argumento scan by column ponemos VERDADERO.

=LET(a;TRANSPONER(A2:B13);b;ORDENAR(a;2;;VERDADERO);c;ORDENAR(b;1;;VERDADERO);d;UNICOS(c;VERDADERO);ENCOL(d;;VERDADERO))

Aceptamos, y, ya lo tenemos.

Miguel Angel Franco