A través de esta función, buscamos un valor en vertical, de ahí, la V final, y, devuelve el número de columnas que le indiquemos.
Sintaxis
Los argumentos de esta función, es valor buscado, es decir, el valor que queremos buscar, el argumento matriz_tabla, es decir, donde vamos a buscar el valor, el siguiente argumento es indicador_columnas, quiere decir, que numero de columna debe de devolver, y, por último argumento, es rango, es decir, si el valor que buscamos, queremos una coincidencia exacta o aproximada.
Sobre el ultimo argumento, rango, debemos de decir, que la coincidencia aproximada, generalmente, se usa cuando buscamos un valor numérico, que no está presente dentro del rango de celdas.
Esta función tiene un inconveniente, por ejemplo, teniendo los siguientes datos, y, el valor buscado es, por ejemplo Stock, no podemos indicar que nos devuelve una de las columnas que se encuentra a la izquierda, por lo que en estos casos, esta función no sería valida.
Veamos un ejemplo, tenemos los siguientes datos.
Lo que queremos es introducir un código, y, rescatar los datos correspondientes a ese código.
En la celda I5, es donde vamos a introducir el código a buscar.
En la celda J5, vamos a introducir el primer BUSCARV, para ello, escribimos el signo igual, seguido del nombre de la función, y, abrimos un paréntesis.
=BUSCARV (
El primer argumento es valor buscado, que será el contenido en la celda I5.
=BUSCARV (I5
Punto y coma, el siguiente argumento es matriz, o, tabla, que es el rango de celdas, en este caso, no voy a seleccionar el encabezado.
=BUSCARV (I5; B5:G14
Punto y coma, el siguiente argumento, es indicador de columnas, que en este caso, el valor a devolver es de la columna 2.
=BUSCARV (I5; B5:G14;2
Punto y coma, y, como ultimo argumento es tipo de coincidencia, que va a ser exacta.
=BUSCARV (I5; B5:G14;2; FALSO)
Aceptamos, y, vemos el producto que corresponde con el código que pongamos.
Ahora, debemos de arrastrar hacia la derecha, pero antes, debemos de fijar el argumento valor buscado, porque siempre estará en dicha celda, y, el argumento tabla, o, matriz, y, una vez que arrastremos hacia la derecha, el argumento indicador de columnas, debemos de ir aumentando 1, para que nos devuelva la siguiente columna.
En este caso, tenemos pocas columnas, por lo que no sería mucho trabajo el cambiar el argumento indicador de columnas, pero y si tuviéramos muchas más columnas, en este caso, ya si tardaremos un poco más, pero podemos crear un contador, para ello, en la celda I3, vamos a escribir el número 1, seleccionamos la celda, y, arrastramos hacia la derecha hasta la última columna, vamos a la pestaña inicio, dentro del grupo edición, desplegamos rellenar, y, seleccionamos series, donde aceptamos, porque los valores predeterminados son válidos.
Ya tenemos el contador.
Bien, lo siguiente es cambiar el argumento indicador de columnas, borramos el número, y, seleccionamos la celda J3.
=BUSCARV (I5; B5:G14; J3; FALSO)
Dejamos esta referencia en relativa, para que al arrastrar hacia la derecha, se actualice, y, vaya tomando los diferentes valores.
Vemos como se ha rellenado los valores con los diferentes datos.
También, el argumento indicador de columnas, podemos rellenarlo como una matriz, para ello, abro unas llaves, escribo el primer número, ponemos la barra invertida, y, vamos poniendo los siguientes números, separado por una barra invertida, una vez que hemos terminado cerramos las llaves.
=BUSCARV ($I$5; $B$5: $G$14; {2\3\4\5\6}; FALSO)
Obtenemos el mismo resultado, pero como una matriz desbordada.
Introducir el código a mano, puede hacer que nos equivoquemos al introducir dicho código, en este caso, podemos crear una validación de datos, donde por obligación debemos de elegir uno de los códigos de la lista, en caso contrario, nos aparecerá el error de no cumple con las restricciones
Para ello, seleccionamos la celda I5, que es donde introducimos el código.
Vamos a la pestaña de datos, dentro del grupo herramientas de datos, hacemos clic en validación de datos.
En la ventana que se abre, en la ventana de permitir desplegamos, y, seleccionamos lista.
En la pestaña origen, seleccionamos los datos que compone la lista, que son los códigos.
Aceptamos, y, con esto ya estaría.
Veamos otro ejemplo, tenemos dos listas, una primera lista con productos del año 2020, y, una segunda lista con productos del año 2021.
¿Qué queremos?
Bien, queremos saber que productos de la lista del año 2021, ya no se encuentran en la lista del año 2020, es decir, es un producto descatalogado.
Para ello, estando en la celda F5, escribimos el signo igual, escribimos el nombre de la función, y, abrimos un paréntesis.
El primer argumento de la función BUSCARV es valor buscado, pues va a ser el valor de la celda D5, que es el primer producto de la lista de productos del año 2021.
=BUSCARV(D5
El siguiente argumento es el rango de celdas donde vamos a buscar, pues, seleccionamos las celdas donde se encuentran los productos del año 2020.
=BUSCARV(D5;B5:B14
El siguiente argumento, es número de columna, es decir, que columna queremos que nos devuelva, como solo tenemos una, pues ponemos el número 1.
=BUSCARV(D5;B5:B14;1
Y, como ultimo argumento, es tipo de coincidencia, que debe de ser exacta.
=BUSCARV(D5;B5:B14;1;FALSO)
Aceptamos, y, arrastramos hacia abajo, pero antes, debemos de fijar el rango de búsqueda, la celda D5, no debemos de fijarla para que al arrastrar se vaya actualizando, y, tome el valor de la celda siguiente.
=BUSCARV(D5;$B$5:$B$14;1;FALSO)
Vemos que donde no aparece el producto buscado, nos muestra un error, quiere decir que ese producto ya no aparece en la lista del año 2021.
Vamos a hacer uso de la función SI.ERROR, para controlar dicho error, donde como primer argumento, que es la expresión para evaluar, será la función anterior, y, como ultimo argumento, que es lo que debe de aparecer en caso de devolver un error dicha función, en este caso, queremos que aparezca producto descatalogado.
=SI.ERROR(BUSCARV(D5;$B$5:$B$14;1;FALSO);"Producto descatalogado")
Arrastramos hacia abajo, y, vemos que donde nos devolvía un error, ahora, aparece producto descatalogado.
Si queremos resaltar las celdas que contienen producto descatalogado, podemos aplicar un formato condicional, para ello, seleccionamos le rango de celdas, vamos a la pestaña de inicio, desplegamos formato condicional, y, seleccionamos reglas para resaltar celdas, en la ventana que se abre a la derecha, seleccionamos es igual a.
En la siguiente ventana, ponemos producto descatalogado, y, dejamos el formato que nos propone, o, podemos cambiarlo.
Y si quiero saber ¿Cuántos productos son descatalogados.?
Para ello, vamos a usar el condicional SI, pero lo vamos a hacer de forma matricial, para ello, preguntamos si en el rango F5:F14, es igual a producto descatalogado, en ese caso, en el argumento valor si verdadero, que pona el número 1, y, en caso de no haber conciencia, en el argumento valor si falso, que ponga un texto en blanco.
=SI(F5:F14="Producto descatalogado";1;"")
Aceptamos, y, vemos como se crea una matriz desbordada, donde pone 1 donde hay coincidencia, y, un texto en blanco donde no la hay.
Ahora, debemos de hacer uso de la función SUMA, donde englobaremos la función anterior, y, ya tenemos el número de productos descatalogados.
=SUMA(SI(F5:F14="Producto descatalogado";1;""))
Vemos que son dos los productos descatalogados.
Y, a que porcentaje equivale los productos descatalogados respecto al total de productos.
Para ello, debemos de dividir el resultado de la función anterior, entre todos los productos.
Para saber el número total de productos, vamos a hacer uso de la función CONTARA, para que nos cuente el número de celdas alfanuméricas.
=SUMA(SI(F5:F14="Producto descatalogado";1;""))/CONTARA(F5:F14)
Lo ponemos en formato de porcentaje, y, equivale al 20% del total de productos.
Veamos otro ejemplo, vendemos camisas por lotes, cada lote tiene un precio, pero quiero comprar 12 camisas, y, dicho número no se encuentra dentro del rango de numero de camisas.
Volvemos a hacer uso de la función BUSCARV, pero en este caso, en el argumento tipo de coincidencia, debe de ser una coincidencia aproximada.
En la celda D10, escribimos el signo igual, seguido del nombre de la función, y, abrimos un paréntesis.
=BUSCARV(
El argumento valor buscado, es el valor que tenemos en la celda C10.
=BUSCARV(C10
El argumento tabla, o, matriz, es el rango de celdas donde tenemos el número de camisas y los precios.
=BUSCARV(C10;B4:C8
El argumento número de columna, en este caso, es la columna 2.
=BUSCARV(C10;B4:C8;2
Y, como argumento tipo de coincidencia, seleccionamos aproximada, que es el valor predeterminado.
=BUSCARV(C10;B4:C8;2;VERDADERO)
Aceptamos, y, vemos que nos devuelve 20, quiere decir que vamos a pagar como si hubiéramos comprado 10 camisas.
Ahora, tenemos los siguientes datos.
¿Qué queremos?
Queremos buscar un código del primer modelo, pero si no encuentra en el primer modelo, debe de buscarlo en el segundo modelo.
Primero, vamos a buscar el código en el primer modelo, para ello, usamos la siguiente sintaxis:
=BUSCARV (B13; B4:F9;4; FALSO)
Si ponemos un código que está dentro del primer modelo, nos devuelve el apellido 2, que es la columna 4.
Pero, y, ¿si escribimos un código del segundo modelo?
Podemos ver que nos devuelve un error.
Bien, hacemos uso de nuevo de la función SI.ERROR, donde la expresión a evaluar es la anterior, y, en caso de error, que busque en el segundo rango.
=SI.ERROR(BUSCARV ($B$13; B4:F9;4; FALSO); BUSCARV ($B$13; H4:L9;4; FALSO))
Vemos como ha quedado solventado el problema.
Antes de ver el siguiente ejemplo, vamos a conocer la función COINCIDIR.
COINCIDIR
La función COINCIDIR, nos devuelve la posición de un valor buscado dentro de un rango.
Esta función tiene 3 argumentos.
El primer argumento es valor buscado, es decir, que valor queremos buscar, el segundo argumento es matriz buscada, donde vamos a buscar el valor, y, como tercer argumento, tipo de coincidencia, que puede ser menor al valor buscado, exacta, o mayor al valor buscado.
Veamos un ejemplo.
Tenemos los siguientes datos.
Vamos a crear una lista a través de validación de datos con los productos, seguimos los pasos explicados anteriormente para crearla, mediante esta lista vamos a seleccionar un producto, y, queremos saber la posición de dicho elemento.
Por ejemplo, seleccionamos Detergente.
En la celda C1, escribimos el signo igual, seguido del nombre de la función, y, abrimos un paréntesis.
=COINCIDIR(
Seleccionamos la celda que contiene el valor a buscar, que es la celda B1.
=COINCIDIR(B1
En el siguiente argumento, especificamos le rango donde vamos a buscar el valor.
=COINCIDIR(B1;A2:A11
Como ultimo argumento, especificamos cero, que es coincidencia exacta.
=COINCIDIR(B1;A2:A11;0)
Aceptamos, y, vemos que nos devuelve la posición 5.
Vamos a ver otro ejemplo, queremos saber cuál es la posición del número menor a 200.
Escribimos el signo igual, seguido del nombre de la función, y, abrimos un paréntesis.
=COINCIDIR(
Ponemos el número 200, que es el valor buscado, como es número no hace falta ponerlo entre comillas dobles.
=COINCIDIR(200
Especificamos el rango donde buscarlo.
=COINCIDIR(200;E2:E11
Y e tipo de coincidencia, ponemos el número 1, que es menor.
=COINCIDIR(200;E2:E11;1)
Aceptamos, y, nos devuelve la posición 6.
Si nos fijamos en el modelo, vemos que la posición 6, corresponde al número 166, que es el primer número menor a 200.
Una vez vista la explicación de la función COINCIDIR, veamos un nuevo ejemplo de la función BUSCARV.
Tenemos los siguientes datos.
Vamos a introducir un código, y, un encabezado horizontal, y, queremos que nos devuelva el valor, por ejemplo, si selecciono el código 1000, y, el encabezado teléfono, me debe de devolver el teléfono para ese código.
En este ejemplo, el problema viene en el argumento indicador de columnas de la función BUSCARV, pues va a depender del encabezado que elijamos, pues es aquí donde debemos de hacer uso de la función COINCIDIR.
Creamos dos listas, una para elegir un código, y, otra para elegir un encabezado.
Elegimos un código, y, un encabezado.
Escribimos el signo igual, seguido del nombre de la función, y, abrimos un paréntesis.
=BUSCARV(
Como argumento valor buscado seleccionamos la celda donde tenemos los códigos.
=BUSCARV(B12
Seleccionamos la matriz donde buscar.
=BUSCARV(B12;B4:F9
Ahora, en el argumento indicador de columnas, es donde debemos de hacer uso de la función COINCIDIR, donde valor buscado es el encabezado que hemos seleccionado, la matriz donde buscar son los encabezados, y, una coincidencia exacta.
=BUSCARV(B12;B4:F9;COINCIDIR(D12;B3:F3;0)
Como ultimo argumento de la función BUSCARV es tipo de coincidencia, que tiene que ser exacta.
=BUSCARV(B12;B4:F9;COINCIDIR(D12;B3:F3;0);FALSO)
Aceptamos, y, vemos como tenemos el valor del encabezado que seleccionemos.
Comments