Encontrar palabras que no se repiten

Tenemos dos columnas con palabras.

En la tercera columna, debe o deben de aparecer las letras comunas en cada primera y segunda cadena.

En la celda C2, ponemos la función LET, creamos una variable, usamos la función EXTRAE, como argumento texto, seleccionamos la celda A2, como argumento posición inicial, usamos la función SECUENCIA, como argumento filas, usamos la función LARGO, como argumento texto, seleccionamos la celda A2, como argumento posición inicial, ponemos 1, probamos variable.

=LET(a;EXTRAE(A2;SECUENCIA(LARGO(A2));1);a)

Como en la celda A2, solo tenemos un carácter, nos devuelve dicho carácter.

Creamos otra variable, la función a usar es la misma que para la variable “a”, pero cambiamos el argumento texto de EXTRAE por “b”, y, cambiamos el argumento texto de LARGO por B2.

=LET(a;EXTRAE(A2;SECUENCIA(LARGO(A2));1);b;EXTRAE(B2;SECUENCIA(LARGO(B2));1)

Como argumento calculo de LET, usamos la función COINCIDIR, como argumento texto buscado, ponemos la variable “a”, como argumento dentro del texto, ponemos la variable “b”, como argumento tipo de coincidencia, seleccionamos exacta.

=LET(a;EXTRAE(A2;SECUENCIA(LARGO(A2));1);b;EXTRAE(B2;SECUENCIA(LARGO(B2));1);COINCIDIR(a;b;0))

Obtenemos el valor 1.

Preguntamos si es numero el resultado de COINCIDIR, en caso afirmativo, que nos devuelva la variable “a”, en caso contrario, que nos devuelva un texto en blanco.

=LET(a;EXTRAE(A2;SECUENCIA(LARGO(A2));1);b;EXTRAE(B2;SECUENCIA(LARGO(B2));1);SI(ESNUMERO(COINCIDIR(a;b;0));a;""))

Como en este caso, tenemos un solo valor, nos devuelve un solo valor, pero hay celdas que mas de 1 carácter, por lo que nos devolverá blanco donde no haya coincidencia, por lo que usamos la función UNIRCADENAS entes del condicional SI, como argumento delimitador, ponemos dobles comillas dobles, ignoramos celdas vacías, como argumento texto1, es la expresión anterior.

=LET(a;EXTRAE(A2;SECUENCIA(LARGO(A2));1);b;EXTRAE(B2;SECUENCIA(LARGO(B2));1);UNIRCADENAS("";VERDADERO;SI(ESNUMERO(COINCIDIR(a;b;0));a;"")))

Aceptamos, arrastramos, y, ya lo tenemos.

Miguel Angel Franco