En el siguiente ejemplo, queremos realizar lo mismo, pero encontrando la función, o, fórmula más corta.
Tenemos los siguientes números.
Cada numero debemos de compararlo con los siguientes valores:
Vamos a empezar, por la que yo creo que es la función más larga, que es SI.ANIDADO.
Voy a preguntar si el valor de la celda A1, es mayor o igual a 1, y, a la vez menor o igual a 40, para ello, usaremos el operador lógico Y, el cual usaremos como argumento prueba lógica.
En caso de ser afirmativo, debe de poner el valor 1.
=SI(Y(A2>=1;A2<=40);1
En caso de no haber coincidencia, en el argumento valor si falso, usamos otro SI, junto con el operador lógico Y, para preguntar, si el valor esta entre 40 y 70, en ese caso, debe de poner el valor 2.
=SI(Y(A2>=1;A2<=40);1;SI(Y(A2>40;A2<=70);2
Si no hay coincidencia, vamos a preguntar si el valor esta entre 70 y 100, en ese caso, debe de poner el valor 3.
Cerramos los paréntesis, y, aceptamos.
=SI(Y(A2>=1;A2<=40);1;SI(Y(A2>40;A2<=70);2;SI(Y(A2>70;A2<=100);3;"")))
Vemos que, para el primer valor, 18, nos devuelve 1, cosa que es correcta, porque esta entre 1 y 40.
Arrastramos hacia abajo, y, por ejemplo, para el numero 97, nos devuelve el numero 3, para el numero 51, nos devuelve el número 2.
Esta expresión tiene 74 caracteres.
Vamos a hacer esta sintaxis mas corta, si nos fijamos en la primera condición, hemos puesto:
=SI(Y(A2>=1;A2<=40);1
Si pongo, solamente, si el valor de la celda A2 es menor a 40, obtendré el mismo resultado, igualmente, si pongo si A2 es menor a 70, que devuelva el numero 2, y, si es menor a 100, que ponga el número 3.
Decir, que para que los resultados sean correctos, deben de tener este orden, es decir, comparar desde el número menor al mayor.
=SI(A2<=40;1;SI(A2<=70;2;SI(A2<=100;3)))
Arrastramos, y, tenemos los mismos resultados.
Esta sintaxis tiene una longitud de 42 caracteres, mucho mas corta que la anterior.
Hagámoslo de otra manera, que va a ser con la función SI.CONJUNTO, donde solo ponemos un SI.
=SI.CONJUNTO(A2<=40;1;A2<=70;2;A2<=100;3)
Obtenemos los mismos resultados, pero esta expresión, tiene una longitud de 40 caracteres.
Veamos otra forma de hacerlo, en esta ocasión, lo haremos con la función BUSCARV, donde buscamos el valor de la celda A2, en el rango I4:J6, que nos devuelva la columna 2, con una coincidencia aproximada.
=BUSCARV(A2;$I$4:$J$6;2;VERDADERO)
Seguimos obteniendo los mismos resultados, pero con una longitud de 33 caracteres.
Vamos a ver otra forma, pero esta vez, con la función BUSCAR, donde vamos a buscar el valor de A2, en el rango I4:I6, y, que nos devuelva el rango J4:J6, la función BUSCAR, realiza una búsqueda aproximada.
=BUSCAR(A2;$I$4:$I$6;$J$4:$J$6)
Seguimos teniendo los mismos resultados, pero con una longitud de 30 caracteres.
Veamos una ultima forma, que va a ser con la función COINCIDIR, vamos a buscar el valor de la celda A2, pero que nos devuelva el siguiente elemento menor.
=COINCIDIR(A2;$I$4:$I$6;1)
Obtenemos los mismos resultados, pero la sintaxis es aún más corta.
Por lo que como ya hemos dicho, en otras ocasiones, lo mismo en Excel se puede hacer de diferentes formas, pero siempre, debemos de crear una formula, o, función que sea entendible.
Kommentarer