Dejar números que no se repiten

Para el siguiente ejemplo, teniendo el siguiente modelo.

Debemos de quitar de cada cadena aquellos números que se repiten, y, dejar solo los números que no se repiten.

En la celda B2, ponemos la función LET, creamos una variable, como valor de la variable, ponemos la función EXTRAE, como argumento texto, seleccionamos la celda A2, como argumento posición inicial, usamos la función SECUENCIA, como argumento filas, usamos la función LARGO, como argumento texto, seleccionamos la celda A2, como argumento numero de caracteres, ponemos 1, probamos variable.

=LET(a;EXTRAE(A2;SECUENCIA(LARGO(A2));1);a)

Obtenemos cada carácter de la celda A2.

Como argumento calculo de LET, usamos la función FRECUENCIA, como argumento datos, usamos la función COINCIDIR, como argumento valor buscado, ponemos la variable “a”, como argumento matriz buscada, volvemos a poner la variable “a”, como tipo de coincidencia, ponemos exacta.

=LET(a;EXTRAE(A2;SECUENCIA(LARGO(A2));1);FRECUENCIA(COINCIDIR(a;a;0)

Como argumento grupos es el mismo coincidir, probamos variable.

=LET(a;EXTRAE(A2;SECUENCIA(LARGO(A2));1);FRECUENCIA(COINCIDIR(a;a;0);COINCIDIR(a;a;0)))

Obtenemos una matriz desbordada con 1 cuando el valor aparece una vez, y, más de uno cuando aparece mas de una vez, vemos que aparecen ceros, pero no los tendremos en cuenta.

Comparamos la función FRECUENCIA con 1.

=LET(a;EXTRAE(A2;SECUENCIA(LARGO(A2));1);FRECUENCIA(COINCIDIR(a;a;0);COINCIDIR(a;a;0))=1)

Obtenemos VERDADERO donde es 1, y, FALSO donde no lo es, nos interesa los 1, que son los valores que no se repiten.

Preguntamos con el condicional SI, que, si el resultado de FRECUENCIA es igual a 1, que nos devuelva la variable “a”, en caso contrario, que nos devuelva un texto en blanco.

=LET(a;EXTRAE(A2;SECUENCIA(LARGO(A2));1);SI(FRECUENCIA(COINCIDIR(a;a;0);COINCIDIR(a;a;0))=1;a;""))

Obtenemos los valores que no repiten y, blanco donde los valores se repiten.

Usamos la función UNIRCADENAS, como argumento delimitador, ponemos dobles comillas dobles, ignoramos celdas vacías, como argumento texto1, es el condicional SI.

=LET(a;EXTRAE(A2;SECUENCIA(LARGO(A2));1);UNIRCADENAS("";VERDADERO;SI(FRECUENCIA(COINCIDIR(a;a;0);COINCIDIR(a;a;0))=1;a;"")))

Aceptamos, arrastramos, y, ya lo tenemos.

Miguel Angel Franco