Cálculo de descuento según cantidad y producto.

Tenemos una serie de productos, con las unidades vendidas y el total.

Tenemos otro modelo donde tenemos los productos, las unidades, y, cada numero de unidades tiene asignado un porcentaje de descuento.

Vamos a trabajar con duplicados.

Para este ejemplo, vamos a usar la función FILTRAR, donde como argumento array, seleccionamos las unidades y el descuento.

=FILTRAR(H3:I16;

Como argumento include, seleccionamos los nombres de productos, y, lo igualamos al valor de la celda A2, es decir, el primer producto del modelo.

Cerramos paréntesis, y, aceptamos.

=FILTRAR(H3:I16;G3:G16=A2)

Obtenemos una matriz desbordada con los porcentajes de descuento, en este caso, para el producto aspiradora.

Ahora, debemos de buscar la cantidad (B2), en la matriz desbordada obtenida anteriormente, para ello, voy a usar la función BUSCARV, donde como argumento valor buscado, es el valor de la celda B2, la primera cantidad, como argumento matriz, es la expresión FILTRAR, como argumento indicador de columnas, ponemos 2, con una coincidencia aproximada, porque es probable, que la cantidad que busquemos no se encuentre en la matriz desbordada.

Cerramos paréntesis, y, aceptamos.

=BUSCARV(B2;FILTRAR(H3:I16;G3:G16=A2);2;VERDADERO)

Obtenemos el porcentaje de descuento, en formato decimal, para el producto aspiradora, con una cantidad de 7.

Fijamos las siguientes referencias.

=BUSCARV(B2;FILTRAR($H$3:$I$16;$G$3:$G$16=A2);2;VERDADERO)

Arrastramos, y, tenemos el descuento por cantidad y producto.

Vamos a añadir una nueva columna, donde vamos a calcular el importe en moneda a que corresponde cada porcentaje, para ello, multiplicamos la columna de total por la columna de descuento.

=[@Total]*[@Descuento]

Ya tenemos nuestro ejercicio completado.