Cuarta cifra

Vamos ahora por la cuarta cifra, este va a ser fácil, porque ya tenemos el primer, segundo, y, tercer carácter, solo tenemos que buscar el cuarto carácter por la derecha, para ello, con la funcion K.ESIMO.MAYOR nos vamos a traer el cuarto índice mayor.

=K.ESIMO.MAYOR(SECUENCIA(LARGO(B1));4)

Extraemos el cuarto carácter por la derecha.

=ABS(EXTRAE(B1;K.ESIMO.MAYOR(SECUENCIA(LARGO(B1));4);1))

Usamos BUSCARX, como argumento valor buscado es la expresión anterior.

=BUSCARX(ABS(EXTRAE(B1;K.ESIMO.MAYOR(SECUENCIA(LARGO(B1));4);1))

Como argumento matriz de búsqueda, seleccionamos el rango H1:H9, como argumento matriz devuelta, seleccionamos el rango M1:M9, como argumento si no se encuentra, ponemos un texto en blanco.

Cerramos paréntesis.

=BUSCARX(ABS(EXTRAE(B1;K.ESIMO.MAYOR(SECUENCIA(LARGO(B1));4);1));H1:H9;M1:M9;"")

Aceptamos, tenemos el siguiente número, donde los 4 últimos caracteres por la derecha son 1211, vemos que en el campo 4 carácter, nos devuelve mil.

Vamos a poner el siguiente número, vemos que nos devuelve el campo 1 carácter, el cual no debería de devolver.

Veamos la expresión del campo 1 carácter, donde vemos que almacenamos en una variable el primer carácter por la derecha, que lo hacemos con la funcion DERECHA.

=LET(a;ABS(DERECHA(B1));SI(Y(a>=11;a<=19);"";FILTRAR(I1:I9;H1:H9=a;"")))

Vamos a cambiar la expresión, aunque va a ser parecida, abrimos un paréntesis, para poner una primera condición, donde usamos la funcion DERECHA y extraemos dos caracteres, lo comparamos con mayor o igual a 11, cerramos paréntesis.

(ABS(DERECHA(B1;2))>=11)

Ponemos el símbolo de asterisco, abrimos otro paréntesis, volvemos a usar la funcion DERECHA, y, comparamos con menor o igual a 19, cerramos paréntesis de la condición.

(ABS(DERECHA(B1;2))>=11)*(ABS(DERECHA(B1;2))<=19)

Aceptamos, y, nos devuelve 1 si las condiciones se cumplen, y, 0 cuando no se cumplen.

Preguntamos que, si la expresión es igual a 1, que ponga un texto en blanco.

=SI((ABS(DERECHA(B1;2))>=11)*(ABS(DERECHA(B1;2))<=19);""

Como argumento valor si falso, usamos la funcion FILTRAR donde como argumento array, es el rango I1:I9, como argumento include, seleccionamos el rango H1:H9 e igualamos al primer carácter por la derecha, como argumento si vacío, ponemos un texto en blanco.

Cerramos paréntesis.

=SI((ABS(DERECHA(B1;2))>=11)*(ABS(DERECHA(B1;2))<=19);"";FILTRAR(I1:I9;H1:H9=ABS(DERECHA(B1));""))

Aceptamos, probamos, y, vemos que si los dos últimos dígitos por la derecha es mayor o igual a 11, y, menor o igual a 19, aparece un texto en blanco.

Miguel Angel Franco