En el siguiente ejemplo, queremos calcular cuantos días de la semana tiene un año, es decir, cuantos lunes, cuantos martes…
En tres celdas, voy a poner año, mes, y, día, donde vamos a introducir dichos datos.
En la celda D2, voy a usar la función FECHA, que tiene tres argumentos, que son año, mes, y, día, dichos valores, son los de las celdas desde A2 a C2.
=FECHA(A2;B2;C2)
Lo siguiente que vamos a hacer, es usar la función SECUENCIA, para crear una matriz de 365 filas, de una columna, y, debe de comenzar a partir de la fecha especificada, por lo que escribimos el signo igual, seguido del nombre de la función, y, abrimos un paréntesis.
=SECUENCIA(
Como argumento filas, ponemos 365.
=SECUENCIA(365;
Como argumento columnas, ponemos 1.
=SECUENCIA(365;1;
Y, como argumento inicio, especificamos la celda con la fecha.
Cerramos paréntesis, y, aceptamos.
=SECUENCIA(365;1;D2)
En este caso, tenemos un calendario desde el día 1 de enero, hasta, el 31 de diciembre del año 2021.
Tenemos el cuadro preparado, con los meses en vertical, y, los días en horizontal, para ser rellenado.
Pues, empecemos.
Vamos a hacer uso de la función TEXTO, abrimos un paréntesis, ponemos la función TEXTO.
=(TEXTO(
Como argumento valor, seleccionamos todas las fechas.
=(TEXTO(G2#;
Como argumento formato, entre comillas dobles, ponemos cuatro D.
=(TEXTO(G2#;"dddd")
Cerramos paréntesis, y, lo igualamos al valor de K2, y, cerramos paréntesis.
=(TEXTO(G2#;"dddd")=K2)
Esta sería la primera condición, comparar cada día de cada fecha con el lunes, ahora, vamos por la segunda condición.
Ponemos el símbolo de asterisco (*), que es igual que el operador lógico Y, es decir, devuelve VERDADERO, si todas las condiciones se cumplen.
Abrimos otro paréntesis, donde de nuevo, ponemos la función TEXTO, como argumento valor, sigue siendo las fechas, como argumento formato, entre comillas dobles, ponemos cuatro M.
Cerramos paréntesis, y, aceptamos.
=(TEXTO(G2#;"dddd")=K2)*(TEXTO(G2#;"mmmm")=J3)
Tenemos una matriz desbordada con ceros, y, unos, uno donde es lunes del mes de enero, y, cero donde no lo es.
Pero, queremos el total, por lo que después del signo igual, ponemos la función SUMA.
=SUMA((TEXTO(G2#;"dddd")=K2)*(TEXTO(G2#;"mmmm")=J3))
Vemos que hay cuatro lunes para el mes de enero.
Ahora debemos de copiar, tanto hacia abajo, como a la derecha, por lo que debemos de fijar G2 para que no se actualice al copiar, fijamos la fila de la referencia K2, para que, al copiar hacia abajo, no se actualice, y, la columna de la referencia J3, para que al copiar hacia la derecha tampoco de actualice.
=SUMA((TEXTO($G$2#;"dddd")=K$2)*(TEXTO($G$2#;"mmmm")=$J3))
Seleccionamos la celda, pulsamos CTRL mas C, para copiar, a continuación, seleccionamos todo el rango, y, pulsamos CTRL más V, para pegar.
Ya tenemos cuantos días aparece cada día de la semana para cada mes.
Si hacemos una autosuma en los días de la semana, veremos que son 52 días.
Podemos cambiar el año, el mes, o, el día.
Lo siguiente, es que quede marcada toda la línea cuyos meses sean de 30 días.
Lo vamos a hacer primero en una celda, para comprobar su funcionamiento, y, después lo llevamos a formato condicional.
Vamos a hacer es una autosuma de cada fila de cada mes, donde vemos cuantos días tiene cada mes.
Tenemos una función llamada RESIDUIO, que devuelve el resto de una división, devuelve 1 cuando la división no es exacta, y, 0 cuando lo es, entonces, voy a dividir cada número entre 3.
=RESIDUO(SUMA(K3:Q3);3)
Arrastramos.
Podemos ver que los meses con treinta días, nos devuelve cero, porque la división es exacta.
Pues, esta es la función para usar en formato condicional, seleccionamos, y, copiamos la función, ahora, seleccionamos los meses, nos vamos a la pestaña de inicio, desplegamos formato condicional, y, seleccionamos nueva regla.
En la ventana que se abre, marcamos la última opción.
Pegamos la función, y, lo igualamos a cero.
Aplicamos un formato, en mi caso, solo voy a tachar el mes.
Aceptamos, y, podemos ver como los meses con 30 días, aparecen tachados.
Comments