En este ejemplo, vamos a ver como podemos filtrar un informe por columnas no contiguas, generalmente, cuando filtramos un informe, nos devuelve todas las columnas, no podemos elegir columnas que no estén contiguas.
Tenemos el siguiente modelo.
Queremos filtrar por provincia, y, producto.
Para este ejemplo, vamos a usar la función FILTRAR.
Lo primero que vamos a hacer es filtrar el modelo desde provincia hasta producto, por la provincia de Jaén.
Escribimos el signo igual, seguido de la función, y, abrimos un paréntesis.
=FILTRAR(
Como argumento matriz, seleccionamos las columnas desde provincia hasta producto.
=FILTRAR(B2:D1476
Punto y coma, como argumento include, seleccionamos la columna de provincia, y, que sea igual a Jaén.
=FILTRAR(B2:D1476;B2:B1476="Jaén")
Aceptamos, y, tenemos nuestro informe filtrado por la provincia de Jaén, pero, de momento, incluye las tres columnas que corresponde con el rango que le hemos especificado, que son, provincia, centro, y, aspiradora.
Pero, no queremos ver la columna de centro comercial.
Para solventar este problema, vamos a usar una constante de matriz.
Para escribir una constante de matriz, debemos de poner las llaves, y, dentro los valores que vamos a usar.
Por ejemplo, la siguiente expresión, nos devolverá una matriz desbordada en vertical con los números 1, 2, y, 3.
={1;2;3}
La siguiente expresión nos devolverá la misma matriz desbordada pero en horizontal.
={1\2\3}
Pues para solventar este problema, vamos a filtrar la expresión anterior, y, en el argumento include, vamos a usar la constante de matriz.
Escribimos el signo igual seguido del nombre de la función.
=FILTRAR(
Como argumento matriz, es la expresión anterior.
=FILTRAR(FILTRAR(B2:D1476;B2:B1476="Jaén")
Punto y coma, en el argumento include, es donde vamos a usar la constante de matriz, ya hemos visto que si como separador de argumentos usamos el punto y coma, la matriz desbordada es en vertical, y, si usamos la barra invertida, nos la dará en horizontal.
Como tenemos que descartar columnas, debemos de usar la barra invertida.
=FILTRAR(FILTRAR(B2:D1476;B2:B1476="Jaén");{1\0\1})
Aceptamos, y, vemos que tenemos nuestra matriz desbordada con las dos columnas que necesitamos, que no están contiguas.
Veamos otro ejemplo, en este caso, vamos a filtrar la matriz por todas las columnas, pero cuyo total sea mayor al valor puesto en la celda L2.
Primero filtramos, y, ponemos la condición.
=FILTRAR(A2:E1476;E2:E1476>L2)
Ahora, volvemos a filtrar, es decir, vamos a filtrar el resultado de la función filtrar que acabamos de crear, y, mediante la constante de matriz, vamos a decidir las columnas que queremos ver.
Para decidir que las columnas que queremos, o, que no queremos ver, debemos de usar 1 y 0, 1,quiere decir que si la queremos ver, y, 0, que no la queremos ver.
=FILTRAR(FILTRAR(A2:E1476;E2:E1476>L2);{1\0\0\1\0})
Aceptamos, y, tenemos una matriz desbordada con las columnas que queremos.
Si quisiéramos los valores únicos de dos columnas no contiguas, seguimos el procedimiento anterior, pero después del signo igual, usamos la función UNICOS.
Comments